c ######################################################################
c #
c #                  AISI 316 SS PROPERTIES PACKAGE
c #                  ------------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of AISI 316 Stainless Steel
c #
c ######################################################################

c ######################################################################
      real function dAISI316(T)
c ######################################################################
c #
c # Density of AISI 316 Stainless Steel
c #
c # Range: 0 <= T <= inf K
c #
c #                        References
c #                        ----------
c # Cryocomp v3.0
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   dAISI316          x    density                           Kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   December 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      

c * local variables

c *      
      dAISI316 = 7900.0
c *

      return
      end
c ######################################################################
      real function cAISI316(T)
c ######################################################################
c #
c # Specific heat of AISI 316 Stainless Steel
c #
c # Range: 1 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # Structural Materials for Superconducting Magnets, data digitised by 
c # B. Wong
c # J.M.Corsan, N.I.Mitchen, The Specific Heat of fifteen SS in the 
c # temperature range 4 K and 300 K, Cryogenics, 19, 11, 1979
c # http://cryogenics.nist.gov/MPropsMAY/316Stainless/316Stainless_rev.htm
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   cAISI316          x    specific heat                     J/Kg K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   December 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     T0
      real     A1,A2,A3
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      real     Tmin,Tmax
      data     A1  / 0.507144881  / ,  A2  / 0.0         / ,
     &         A3  / 0.000285531 /
      data     AA  /-16959.92742  / ,  BB  / 0.0         / ,
     &         CC  / 4697.766752  / ,  DD  / 652.0983826 / 
      data     a   / 235.2147394  / ,  b   / 1.0         / ,
     &         c   / 41.60676018  / ,  d   / 1.789379282 / 
      data     na  / 0.921771058  / ,  nb  / 1.0         / ,
     &         nc  / 2.829621677  / ,  nd  / 3.570284974 / 
      data     T0  / 18.20493149  /
      data     Tmin / 1.0/, Tmax / 300.0/
      save    
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      if(TT.le.T0) then

         cAISI316 = A1*T + A2*T**2 + A3*TT**3

      else
      
         cAISI316 = AA*TT   /(a+TT)**na + BB*TT**2/(b+TT)**nb + 
     &              CC*TT**3/(c+TT)**nc + DD*TT**4/(d+TT)**nd       

      endif

c *
      return
      end
c ######################################################################
      real function kAISI316(T)
c ######################################################################
c #
c # Thermal conductivity of AISI 316 Stainless Steel
c #
c # Range: 0.1 <= T <= 1644 K
c #
c #                        References
c #                        ----------
c # Structural Materials for Superconducting Magnets, data digitised by 
c # B. Wong
c # http://cryogenics.nist.gov/MPropsMAY/316Stainless/316Stainless_rev.htm
c # C.T.Ho, T.K. Chu, Electrical resistivity and thermal conductivity of 
c # nine selected AISI stainless steels, CINDAS Report 45, 1977
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   kAISI316          x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   December 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      real     Tmin,Tmax
      data     AA  / 0.0          / ,  BB  / 0.0          / ,
     &         CC  / 326.9104089  / ,  DD  / 0.079389078  / 
      data     a   / 1.0          / ,  b   / 1.0          / ,
     &         c   / 38.31647264  / ,  d   / 0.017685624  / 
      data     na  / 1.0          / ,  nb  / 1.0          / ,
     &         nc  / 3.62543695   / ,  nd  / 3.194561039  / 
      data     Tmin / 0.1/, Tmax / 1644.0/
      save    
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      kAISI316 = AA*TT   /(a+TT)**na + BB*TT**2/(b+TT)**nb + 
     &              CC*TT**3/(c+TT)**nc + DD*TT**4/(d+TT)**nd       

c *
      return
      end
c ######################################################################
      real function rAISI316(T)
c ######################################################################
c #
c # Electrical resistivity of AISI 316 Stainless Steel
c #
c # Range: 0 <= T <= 1644 K
c #
c #                        References
c #                        ----------
c # Cryocomp v3.0
c # Handbook on Materials for S.C. Machinery, NBS Boulder (yellow book), 
c # 1977
c # C.T.Ho, T.K. Chu, Electrical resistivity and thermal conductivity of 
c # nine selected AISI stainless steels, CINDAS Report 45, 1977
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   rAISI316          x    resistivity                       Ohm m
c #
c # Author : L.Bottura at CryoSoft
c # Version: 1.0   December 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     A,B,nb
      real     Tmin,Tmax
      data     A   / 5.1 / ,  B  / 0.006252787 / ,
     &         nb  / 1.0 /
      data     Tmin   / 0.0/, Tmax   / 1644.0/
      save
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      rAISI316 = 1.0e-7 * (A + B*TT**nb)
	
c *
      return
      end