c ######################################################################
c #
c #                  Al-6063 PROPERTIES PACKAGE
c #                  --------------------------
c # Contains functions for the calculation of the thermal and electrical
c # properties of Al alloy 6063
c #
c ######################################################################

c ######################################################################
      real function dAl6063(T)
c ######################################################################
c #
c # Density of Al alloy 6063
c #
c # Range: 0 <= T <= inf K
c #
c #                        References
c #                        ----------
c # http://asm.matweb.com/search/SpecificMaterial.asp?bassnum=MA6063T6
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   dAl6063           x    density                           kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   March 2013
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      

c * local variables

c *      
      dAl6063 = 2700.0
c *

      return
      end
c ######################################################################
      real function cAl6063(T)
c ######################################################################
c #
c # Specific heat of Al alloy 6063
c #
c # Range: 1 <= T <= 1000 K
c #
c #                        references
c #                        ----------
c # CryoComp Version 3.0                        
c # V.J. Johnson, Properties of Materials at Low Temperatures (Phase 1)
c # Pergamon Press, 1961
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   cTi6Al4V          x    specific heat                     J/kg K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 4.1   March 2013
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      
      real     T0,T1
      real     Tmin,Tmax
      real     a0,a1,a2,a3
      real     b0,b1,b2,b3,b4
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      data     T0  /   13.0300576 / ,  T1  /  54.4990277  /
      data     a0  /  0.012034041 / ,  a1  /  0.039172353 /, 
     &         a2  /  0.002543257 / ,  a3  /  0.000771961 /
      data     b0  / -4.797655015 / ,  b1  /  1.249154424 /, 
     &         b2  / -0.105581366 / ,  b3  /  0.004593931 /, 
     &         b4  / -3.65654e-05 /
      data     AA  /   9143.27476 / ,  BB  /   -417.10708 / ,
     &         CC  /   400.787649 / ,  DD  /   -7722.6604 / 
      data     a   /  -18.6481086 / ,  b   /  -25.7545827 / ,
     &         c   /  -18.1481600 / ,  d   /  -5.44742024 / 
      data     na  /   0.73861474 / ,  nb  /   1.52610058 / ,
     &         nc  /   2.48698565 / ,  nd  /   3.70977399 / 
      Data     Tmin / 1.0/, Tmax / 1000.0/
      save    
c * local variables
      real     TT
c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
      
      if (TT.le.T0) then
         cAl6063 = a0 + a1*TT + a2*TT**2 + a3*TT**3            
      elseif (TT.gt.T0 .and. TT.le.T1) then
         cAl6063 = b0 + b1*TT + b2*TT**2 + b3*TT**3 + b4*TT**4      
      elseif(TT.gt.T1) then
         cAl6063 = AA*TT   /(a+TT)**na + BB*TT**2/(b+TT)**nb + 
     &             CC*TT**3/(c+TT)**nc + DD*TT**4/(d+TT)**nd
      endif
c *
      return
      end
c ######################################################################
      real function kAl6063(T)
c ######################################################################
c #
c # Thermal conductivity of Al alloy 6063
c #
c # Range: 2 <= T <= 1000 K
c #
c #                        References
c #                        ----------
c # P.Reed & A.F.Clark, Materials at low Temperature, ASM, 1983 (hand
c # picked-up data points, but good accuracy)
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   kAl6063           x    thermal conductivity              W/m K
c # variable    I/O               meaning                        units
c #
c # Author : L.Bottura at Cryosoft
c # Version: 4.1   November 2013
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      
      real     k0,k1,k2
      real     km,Tm
      real     alpha,beta,n,m
      real     Tmin,Tmax
      data     k0   /  0.235849406 / , k1   /  1.453488276 /,
     &         k2   / -0.003823466 /
      data     km   /  577.3864993 / , Tm   /  5.282286082 /
      data     alpha/  1.030082721 / , beta /  91.91507966 /,
     &         n    /  0.602305758 / , m    /  1.191691368 /
      data     Tmin / 2.0/, Tmax / 1000.0/
      save    
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
      
      kAl6063 = k0 + k1*TT/Tm + k2*(TT/Tm)**2 + 
     &          km * 3/(alpha*(TT/Tm)**n+beta/(TT/Tm)**m)

c *
      return
      end
c ######################################################################
      real function rAl6063(T)
c ######################################################################
c #
c # Electrical resistivity of Al alloy 6063
c #
c # Range: 2 <= T <= 1000 K
c #
c #                        References
c #                        ----------
c # P.Reed & A.F.Clark, Materials at low Temperature, ASM, 1983 (hand
c # picked-up data points, but good accuracy)
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   rAl6063           x    resistivity                       Ohm m
c #
c # Author : L.Bottura at Cryosoft
c # Version: 4.1   November 2013
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     Tmin,Tmax
      parameter(Tmin   = 2.0, Tmax   = 1000.0)
      real     rho0
      parameter(rho0=5.76e-9)
      real     p1,p2,p3,p4,p5,p6
      parameter(p1=6.44e-16, p2=3.56, p3=1.28e10,
     &          p4=-1.05, p5=84.0, p6=4.72)
c * local variables   
      real     TT,arg,rhoi

c *
      TT=T
      TT=max(TT,Tmin)
      TT=min(TT,Tmax)

c * resistivity at the temperature t
      arg     = min((p5/TT)**p6,30.0)
      rhoi    = p1*TT**p2/(1.+p1*p3*TT**(p2+p4)*exp(-arg))

c * resistivity
      rAl6063 = rho0 + rhoi
	
c *
      return
      end