c ######################################################################
c #
c #                  ALUMINA PROPERTIES PACKAGE
c #                  --------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of Alumina (Al2O3 ceramics)
c #
c ######################################################################

c ######################################################################
      real function dAlumina(T)
c ######################################################################
c #
c # Density of Alumina (Al2O3 ceramics))
c #
c # Range: 0 <= T <= inf K
c #
c #                        References
c #                        ----------
c # W. Martienssen, H. Warlimont, Springer Handbook of Condensed Matter 
c # and Materials Data, Springer, 2005
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   dAlumina          x    density                           Kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   October 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      

c * local variables

c *      
      dAlumina = 3925.0
c *

      return
      end
c ######################################################################
      real function cAlumina(T)
c ######################################################################
c #
c # Specific heat of Alumina (Al2O3 ceramics)
c #
c # Range: 5 <= T <= 720 K
c #
c #                        References
c #                        ----------
c # G.T. Furukawa, et al., J. Research of the NBS, 57(2), 67, 1956
c # D. A. Ditmars, et. al., J. Res. Nat. Bur. Stand., 87, (2), 159-163, 
c # 1982
c # the data corresponds to heat capacity of sapphire, which is one of 
c # the reference materials used for qualification of measurement systems
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   cAlumina          x    specific heat                     J/Kg K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   October 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     T0,T1
      real     Tmin,Tmax
      real     a1,a2,a3
      real     b0,b1,b2,b3,b4
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      data     T0  /   21.5529877 / ,  T1  /  94.53654468 /
      data     a1  /  -0.00032243 / ,  a2  /  0.0         / , 
     &         a3  /   9.1281E-05 /
      data     b0  /  -6.19214890 / ,  b1  /   0.73374087 / , 
     &         b2  /  -0.03088312 / ,  b3  /   0.00061707 / ,
     &         b4  /  -2.5357E-06 /
      data     AA  / -1744.380057 / ,  BB  /  10109.50483 /,
     &         CC  /  93.94645579 / ,  DD  /  0.0         /
      data     a   /  1096.721481 / ,  b   / 237.798873   /,
     &         c   /  804.5077295 / ,  d   /  1.0         /
      data     na  /  0.847099548 / ,  nb  /  2.079754448 /,
     &         nc  /  7.399735317 / ,  nd  /  1.0         /
      data     Tmin / 5.0/, Tmax / 720.0/
      save    

c * local variables   
      real     TT

c *
      TT=T
      TT=max(TT,Tmin)
      TT=min(TT,Tmax)
      
      if (TT.le.t0) then
         cAlumina = a1*TT + a2*TT**2 + a3*TT**3            
      elseif (TT.gt.t0 .and. TT.le.t1) then
         cAlumina = b0 + b1*TT+ b2*TT**2 + b3*TT**3 + b4*TT**4      
      elseif(TT.gt.t1) then
         cAlumina = AA*TT   /(a+TT)**na + BB*TT**2/(b+TT)**nb +
     &         CC*TT**3/(c+TT)**nc + DD*TT**4/(d+TT)**nd
      endif

c *
      return
      end
c ######################################################################
      real function kAlumina(T)
c ######################################################################
c #
c # Thermal conductivity of Alumina (a mix of various data)
c #
c # Range: 2 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # CryoComp v3.0
c # data digitized by B. Wong (MIT) from G. Hartwig, Low Temperature 
c # Properties of Resins and their Correlations, Adv. Cryo. Eng., 22, 
c # 283, 1976
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   kAlumina            x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.1   December 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      
      real     A1,Tl1,Th1,o1,s1
      real     A2,Tl2,Th2,o2,s2
      real     Tmin,Tmax

      data     A1  /  2.2788      / , Tl1 /  7.173983    / ,
     &         Th1 /  3.576855    / , o1  /  1.353636    / ,
     &         s1  /  0.000000000 / 
      data     A2  /  76.4923     / , Tl2 /  38.352282   / ,
     &         Th2 /  189.722920  / , o2  /  2.637244 / ,
     &         s2  /  0.000000000 /
 
      data     Tmin / 2.0/, Tmax / 300.0/
      save  
  
c * local variables
      real     TT
c *
      TT=T
      TT=max(TT,Tmin)
      TT=min(TT,Tmax)
      
      kAlumina =  A1*TT**s1 * (TT/Tl1)**o1 / 
     &          ( sqrt(1+(TT/Tl1)**(2*o1)) * sqrt(1+(TT/Th1)**(2*o1)) )+
     &            A2*TT**s2 * (TT/Tl2)**o2 / 
     &          ( sqrt(1+(TT/Tl2)**(2*o2)) * sqrt(1+(TT/Th2)**(2*o2)) )

c *
      return
      end