c ######################################################################
c #
c #                      CuMn PROPERTIES PACKAGE
c #                  ------------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of Cu-Mn as a function of alloy Mn percentage by weight
c #
c ######################################################################

c ######################################################################
      real function dCuMn(T,W)
c ######################################################################
c #
c # Density of Cu-W%Mn as a function of Mn percentage
c #
c # Range: 0 <= T <= Inf K
c #        0 <= W <= 12 %
c #
c #                        References
c #                        ----------
c # https://www.indium.com/blog/interest-in-formula-for-calculating-
C # Alloy-density-still-keen-1.php
c # https://www.southampton.ac.uk/~pasr1/g7.htm
c #
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Mn           %
c #   dCuMn             x    density                           kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   May 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables      
      real     MCu,MMn
      real     Wmin,Wmax
      data     MCu  / 63.546 / , MMn  / 54.938044 /
      data     Wmin / 0.0    / , Wmax /  12.0  /
c * local variables
      real     WW,wt,at
      real     dCu,dMn
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)

c * compute atomic weight
      wt = WW/100.0
      at = wt/MMn / (wt/MMn + (1.0-wt)/MCu)

c *
      dCuMn = 1.0 / (wt/dMn(T) + (1.0-wt)/dCu(T))

c *
      return
      end
c ######################################################################
      real function cCuMn(T,W)
c ######################################################################
c #
c # Specific heat of Cu-W%Mn as a function of Ni percentage
c #
c # Range:   1 <= T <= 300 K
c #          0 <= W <= 12 %
c #
c #                        References
c #                        ----------
c #
c # Y.S. Toulokian, et al, Specific Heat - Metallic Elements and Alloys, 
c # 1970
c # D. Richter, CERN, Private Communication, 2008
c # P. Duthil, Materials properties at low temperature, CERN Accelerator 
c # School, Erice, 2013
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Mn           %
c #   cCuMn             x    specific heat                     J/Kg K
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   May 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables
      real     MCu,MMn
      real     Tmin,Tmax,Wmin,Wmax
      data     MCu  / 63.546 / , MMn  / 54.938044 /
      data     Tmin  /  1.0 / , Tmax / 300.0/
      data     Wmin  /  0.0 / , Wmax /  12.0 /

c * local variables
      real     TT,WW,wt,at
      real     cCu,cMn

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)

c * compute atomic weight
      wt = WW/100.0
      at = wt/MMn / (wt/MMn + (1.0-wt)/MCu)

c *
      cCuMn = wt*cMn(T) + (1.0-wt)*cCu(T)

c *
      return
      end
c ######################################################################
      real function kCuMn(T,W)
c ######################################################################
c #
c # Thermal conductivity of Cu-W%Mn as a function of Mn percentage
c #
c # Range:  1 <= T <= 600 K
c #         0 <= W <= 12 %
c #
c #                        References
c #                        ----------
c # P. Duthil, Materials properties at low temperature, CERN Accelerator 
c # School, Erice, 2013
c # R.L. Powell, C.Y. Ho, P.E. Liley, Thermal Conductivity of Selected 
c # Materials, NSRDS-NBS 8, 1966
c # R.L. Powell, W.A. Blanpied, Thermal Conductivity of Metals and Alloys 
c # at Low Temperatures, NBS Circular 556, 1954
c # Y.S. Toulokian, R.W. Powell, C.Y. Ho, P.G. Klemens, Thermal 
c # Conductyivity Metallic Elements and Alloys, Plenum, 1970
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Mn           %
c #   kCuMn             x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   May 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables      
      real     A,alpha,nalpha,beta,nbeta
      real     rho273,c
      real     MCu,MMn
      real     Tmin,Tmax,Wmin,Wmax
      data     A      / 7.0         / 
      data     alpha  / 0.0064      /
      data     nalpha / 0.705347823 / 
      data     beta   / 75.5        / 
      data     nbeta  / 1.629873887 /
      data     rho273 / 1.54e-8     / 
      data     c      / 2.72e-6     /
      data     MCu  / 63.546 / , MMn  / 54.938044 /
      data     Tmin  /  1.0 / , Tmax / 600.0/
      data     Wmin  /  0.0 / , Wmax /  12.0 /

c * local variables
      real     TT,WW,RRR,wt,at,wCu,T0,kAdd
      real     kCu

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)

c * compute atomic weight
      wt = WW/100.0
      at = wt/MMn / (wt/MMn + (1.0-wt)/MCu)

c * compute the effective RRR of the alloy
      RRR = 1.0 + rho273/(c*at)

c * copper thermal resistivity (ignoring magneto-resistivity)
      wCu = 1.0/kCu(TT,0.0,RRR)

c * additional thermal conductivity at high wt%
      T0   = ((beta*nbeta)/(alpha*nalpha))**(1.0/(nalpha+nbeta))
      kAdd = A * (alpha*T0**nalpha + beta/T0**nbeta)/
     &           (alpha*TT**nalpha + beta/TT**nbeta)

c *
      kCuMn = 1.0 / wCu + kAdd
c *

      return
      end
c ######################################################################
      real function rCuMn(T,W)
c ######################################################################
c #
c # Electrical resistivity of Cu-W%Mn as a function of Ni percentage
c #
c # Range:  1 <= T <= 300 K
c #        10 <= W <= 50 %
c #
c #                        References
c #                        ----------
c # D. Richter, CERN, Private Communication, 2008
c # Vedernikov, IEEE Trans. Mag. 32(4), 2890-2893, 1996
c # Ashan, Supercollider 1, 1989
c # Schmitt, J. Phys. Chem. Solids, 1957, 3, 324-3337
c # Misjak, Journal of Applied Physics 116, 083507, 2014
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Mn           %
c #   rCuMn             x    resistivity                       Ohm m
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   May 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables
      real     rho0Mn
      real     MCu,MMn
      real     Tmin,Tmax,Wmin,Wmax
      data     rho0Mn / 2.5e-6 /
      data     MCu    / 63.546 / , MMn  / 54.938044 /
      data     Tmin   /  1.0   / , Tmax / 300.0/
      data     Wmin   /  0.0   / , Wmax /  12.0 /

c * local variables
      real     TT,WW,wt,at
      real     rhoiCu

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)

c * compute atomic weight
      wt = WW/100.0
      at = wt/MMn / (wt/MMn + (1.0-wt)/MCu)

c *
      rCuMn = at * rho0Mn + (1.0-at) * rhoiCu(TT)
c *

      return
      end