c ######################################################################
c #
c #                      CuNi PROPERTIES PACKAGE
c #                  ------------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of Cu-Ni as a function of alloy Ni percentage by weight
c #
c ######################################################################

c ######################################################################
      real function dCuNi(T,W)
c ######################################################################
c #
c # Density of Cu-W%Ni as a function of Ni percentage
c #
c # Range: 0 <= T <= Inf K
c #        0 <= W <= 50 %
c #
c #                        References
c #                        ----------
c # https://en.wikipedia.org/wiki/Cupronickel
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Ni           %
c #   dCuNi             x    density                           kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   April 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables      
      real     A,B
      real     Wmin,Wmax
      data     A    / 8.8843 / , B    / 0.0017 /
      data     Wmin / 0.0    / , Wmax /  50.0  /
c * local variables
      real     WW

c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)
c *      
      dCuNi = A + B*WW
c *

      return
      end
c ######################################################################
      real function cCuNi(T,W)
c ######################################################################
c #
c # Specific heat of Cu-W%Ni as a function of Ni percentage
c #
c # Range:  1 <= T <= 300 K
c #        10 <= W <= 50 %
c #
c #                        References
c #                        ----------
c #
c # V.J. Johnson, Properties of materials at low temperatures (phase 1),
c # Pergamon Press, 1961
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Ni           %
c #   cCuNi             x    specific heat                     J/Kg K
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   April 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables
      real     T0
      real     a1Ni,a2Ni,a3Ni,a4Ni
      real     a1Cu,a2Cu,a3Cu,a4Cu
      real     AA,Ta,na
      real     Tmin,Tmax,Wmin,Wmax
      data     a1Ni  / 1.102212e-1 / , a2Ni  / 5.953630e-3 /
      data     a3Ni  /-3.044000e-4 / , a4Ni  / 3.178435e-5 /
      data     a1Cu  / 1.626729e-2 / , a2Cu  /-1.814895e-3 /
      data     a3Cu  / 7.698782e-4 / , a4Cu  / 9.467558e-6 /
      data     AA    / 395.0 /
      data     Ta    / 74.31809825 /
      data     na    / 3.016848462 /
      data     T0    / 14.46659559 /
      data     Tmin  /  1.0 / , Tmax / 300.0/
      data     Wmin  / 10.0 / , Wmax /  50.0 /

c * local variables
      real     TT,WW
      real     lowTCu,lowTNi

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)
c *      

      if(TT.le.T0) then

         lowTCu = a1Cu*TT + a2Cu*TT**2 + a3Cu*TT**3 + a4Cu*TT**4
         lowTNi = a1Ni*TT + a2Ni*TT**2 + a3Ni*TT**3 + a4Ni*TT**4
         cCuNi  = (100.0-WW)/100.0 * lowTCu + WW/100.0 * lowTNi

      else
      
         cCuNi = AA*(TT/Ta)**na/(1+(TT/Ta)**na) 

      endif

c *
      return
      end
c ######################################################################
      real function kCuNi(T,W)
c ######################################################################
c #
c # Thermal conductivity of Cu-W%Ni as a function of Ni percentage
c #
c # Range:  1 <= T <= 1173 K
c #         6 <= W <= 50 %
c #
c #                        References
c #                        ----------
c # Reference
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Ni           %
c #   kCuNi             x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   April 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables      
      real     T0
      real     aA,bA,cA
      real     aB,bB,cB
      real     nA,TA,nB,TB
      real     Tmin,Tmax,Wmin,Wmax
      data     aA / 0.0       / 
      data     bA / 500.0     /
      data     cA / 0.9       / 
      data     aB / 0.0       / 
      data     bB / 3.5710293 /
      data     cB / 0.9442179 / 
      data     nA / 1.7277294 /
      data     TA / 30.392893 /
      data     nB / 3.0       /
      data     TB / 1000.0    /
      data     Tmin  /  1.0 / , Tmax / 1173.0/
      data     Wmin  /  6.0 / , Wmax /   50.0 /

c * local variables
      real     TT,WW,A,B

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)

c *
      A     = aA + bA / WW**cA
      B     = aB + bB * WW**cB
      kCuNi = A * (TT/TA)**nA / (1.0+(TT/TA)**nA) + B * (TT/TB)**nB

c *

      return
      end
c ######################################################################
      real function rCuNi(T,W)
c ######################################################################
c #
c # Electrical resistivity of Cu-W%Ni as a function of Ni percentage
c #
c # Range:  1 <= T <= 1100 K
c #        10 <= W <= 50 %
c #
c #                        References
c #                        ----------
c # Reference
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Ni           %
c #   rCuNi             x    resistivity                       Ohm m
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   April 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables
      real     a1,a2
      real     b1,b2
      real     nB
      real     Tmin,Tmax,Wmin,Wmax
      data     a1 / 0.1117     / 
      data     a2 / 0.1367     /
      data     b1 /-0.0002     / 
      data     b2 / 0.0095     /
      data     nB / 0.68462802 /

      data     Tmin  /   1.0 / , Tmax / 1100.0/
      data     Wmin  /  10.0 / , Wmax /   50.0 /

c * local variables
      real     TT,WW,A,B

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)

c *
      A     = a1 * WW + a2
      B     = b1 * WW + b2
      rCuNi = 1.0e-7 * (A + B * TT**nB)
c *

      return
      end