c ######################################################################
c #
c #                      CuSn PROPERTIES PACKAGE
c #                  ------------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of Cu-Sn as a function of alloy Sn percentage by weight
c #
c ######################################################################

c ######################################################################
      real function dCuSn(T,W)
c ######################################################################
c #
c # Density of Cu-W%Ni as a function of Ni percentage
c #
c # Range: 0 <= T <= Inf K
c #        0 <= W <= 100 %
c #
c #                        References
c #                        ----------
c # 
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Sn           %
c #   dCuSn             x    density                           kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   April 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables      
      real     A,T0,n
      real     Wmin,Wmax
      data     A  /   8.8929966e3 /
      data     T0 / 166.9684659   /
      data     n  /   2.6088228   /
      data     Wmin  /  0.0 / , Wmax / 100.0 /

c * local variables
      real     WW
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)
      
c *      
      dCuSn = A * (T0/T)**n / (1+(T0/T)**n)
c *

      return
      end
c ######################################################################
      real function cCuSn(T,W)
c ######################################################################
c #
c # Specific heat of Cu-W%Sn as a function of Sn percentage
c #
c # Range:  4 <= T <= 550 K
c #         0 <= W <= 100 %
c #
c #                        References
c #                        ----------
c #
c # http://www.engineersedge.com/properties_of_metals.htm
c # N.J. Simon, E.S. Drexler, R.P. Reed, Properties of Copper and Copper 
c # Alloys at Cryogenic Temperatures, NIST Monograph 177, 1992
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Sn           %
c #   cCuSn             x    specific heat                     J/Kg K
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   April 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables
      real     T0
      real     a1,a2,a3,a4
      real     AA,BB,Ta,Tb,na,nb
      real     Tmin,Tmax,Wmin,Wmax
      data     a1  / 1.167267E-02 / , a2  / 6.546153E-07 /
      data     a3  / 8.913366E-04 / , a4  / 1.233920E-05 /
      data     AA  / 106.2305432  /
      data     Ta  / 55.22278056 /
      data     na  / 4.003210193 /
      data     BB  / 261.1607592 /
      data     Tb  / 97.59025351 /
      data     nb  / 2.388246089 /
      data     T0  / 12.5514554  /
      data     Tmin  /  4.0 / , Tmax  / 550.0/
      data     Wmin  /  0.0 / , Wmax  / 100.0 /

c * local variables
      real     TT,WW

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)
c *      

      if(TT.le.T0) then

         cCuSn = a1*TT + a2*TT**2 + a3*TT**3 + a4*TT**4

      else
      
         cCuSn = AA*(TT/Ta)**na/(1+(TT/Ta)**na) + 
     &           BB*(TT/Tb)**nb/(1+(TT/Tb)**nb)

      endif

c *
      return
      end
c ######################################################################
      real function kCuSn(T,W)
c ######################################################################
c #
c # Thermal conductivity of Cu-W%Sn as a function of Sn percentage
c #
c # Range:  1   <= T <= 550 K
c #         1.5 <= W <= 25 %
c #
c #                        References
c #                        ----------
c # Reference
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Sn           %
c #   kCuSn             x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   April 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables      
      real     alpha,beta,gamma
      real     n1,n2,T0
      real     Tmin,Tmax,Wmin,Wmax
      data     alpha / 0.746437948 / 
      data     beta  / 201.2494341 /
      data     gamma / 0.82272204  / 
      data     n1    / 1.34865192  /
      data     n2    / 1.010720785 / 
      data     T0    / 39.71517813 /
      data     Tmin  /  1.5 / , Tmax  /  550.0/
      data     Wmin  /  1.0 / , Wmax /   25.0 /

c * local variables
      real     TT,WW,A

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)

c *
      A     = alpha+beta/WW**gamma
      kCuSn = A * (TT/T0)**n1 / (1.0+(TT/T0)**n2)

c *

      return
      end
c ######################################################################
      real function rCuSn(T,W)
c ######################################################################
c #
c # Electrical resistivity of Cu-W%Sn as a function of Sn percentage
c #
c # Range:  1 <= T <= 550 K
c #         1 <= W <= 15 %
c #
c #                        References
c #                        ----------
c # Reference
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   W               x      weight percentage of Sn           %
c #   rCuSn             x    resistivity                       Ohm m
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   April 2020
c #
c ######################################################################
      implicit none
c * external variables
      real     T,W
c * fit variables
      real     A,B,C
      real     Tmin,Tmax,Wmin,Wmax
      data     A / 0.071842918 / 
      data     B / 13.61993322 /
      data     C / 0.988589131 / 

      data     Tmin  /   1.0 /, Tmax  / 550.0/
      data     Wmin  /   1.0 /, Wmax /   15.0 /

c * local variables
      real     TT,WW

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
c *
      WW=W
      WW=min(WW,Wmax)
      WW=max(WW,Wmin)

c *
      rCuSn = 1.0e-9 * (A * TT + B * WW + C)
c *

      return
      end