c ######################################################################
c #
c #                  EPOXIES PROPERTIES PACKAGE
c #                  --------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of Epoxies (typically Araldite)
c #
c ######################################################################

c ######################################################################
      real function dEpoxy(T)
c ######################################################################
c #
c # Density of Epoxy (Araldite-B)
c #
c # Range: 0 <= T <= inf K
c #
c #                        References
c #                        ----------
c # VDI-Richtlinien, VDI2010 Blatt 3
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   dEpoxy            x    density                           Kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   October 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      

c * local variables

c *      
      dEpoxy = 1220.0
c *

      return
      end
c ######################################################################
      real function cEpoxy(T)
c ######################################################################
c #
c # Specific heat of Epoxy (a mix of various data)
c #
c # Range: 1 <= T <= 400 K
c #
c #                        References
c #                        ----------
c # CryoComp v3.0
c # data digitized by B. Wong (MIT) from G. Hartwig, Low Temperature 
c # Properties of Resins and their Correlations, Adv. Cryo. Eng., 22, 
c # 283, 1976
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   cEpoxy            x    specific heat                     J/Kg K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   October 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      real     Tmin,Tmax
      data     AA  /  1.01E-03   / ,  BB  /   1.95E-02   / ,
     &         CC  /  9.10E-03   / ,  DD  /   3.24E-07   / 
      data     a   /  0.00100016 / ,  b   /   1.46884569 / ,
     &         c   / 21.15674346 / ,  d   / 292.8732216  / 
      data     na  /  0.98828237 / ,  nb  /   0.61405644 / ,
     &         nc  /  3.88220297 / ,  nd  /   4.28470778 / 
      data     Tmin / 1.0/, Tmax / 400.0/
      save    
c * local variables
      real     TT
c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
      
      cEpoxy = AA*TT**na/(1+TT/a)**na + BB*TT**nb/(1+TT/b)**nb + 
     &         CC*TT**nc/(1+TT/c)**nc + DD*TT**nd/(1+TT/d)**nd       
c *
      return
      end
c ######################################################################
      real function kEpoxy(T)
c ######################################################################
c #
c # Thermal conductivity of Epoxy (a mix of various data)
c #
c # Range: 1 <= T <= 400 K
c #
c #                        References
c #                        ----------
c # CryoComp v3.0
c # data digitized by B. Wong (MIT) from G. Hartwig, Low Temperature 
c # Properties of Resins and their Correlations, Adv. Cryo. Eng., 22, 
c # 283, 1976
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   kEpoxy            x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   October 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      real     Tmin,Tmax
      data     AA  /  0.051775951 / ,  BB  /   0.401290937 / ,
     &         CC  /  0.024460264 / ,  DD  /   0.0         / 
      data     a   /  1.414607305 / ,  b   /   62.25292488 / ,
     &         c   /  286.9589245 / ,  d   /   1.0         / 
      data     na  /  0.939431222 / ,  nb  /   2.12830256  / ,
     &         nc  /  5.094838457 / ,  nd  /   1.0         / 
      data     Tmin / 1.0/, Tmax / 400.0/
      save
c * local variables
      real     TT
c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
      
      kEpoxy = AA*TT   /(a+TT)**na + BB*TT**2/(b+TT)**nb + 
     &         CC*TT**3/(c+TT)**nc + DD*TT**4/(d+TT)**nd        
c *

      return
      end