c ######################################################################
c #
c #                  INCONEL 718 PROPERTIES PACKAGE
c #                  ------------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of Inconel 718 (SMC Nickel-Chromium superalloy)
c #
c ######################################################################

c ######################################################################
      real function dInconel718(T)
c ######################################################################
c #
c # Density of Inconel 718
c #
c # Range: 0 <= T <= inf K
c #
c #                        References
c #                        ----------
c # Cryocomp v3.0
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   dInconel718       x    density                           Kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   December 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      

c * local variables

c *      
      dInconel718 = 8193.0
c *

      return
      end
c ######################################################################
      real function cInconel718(T)
c ######################################################################
c #
c # Density of Inconel 718
c #
c # Range: 1 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # J.Lu, E.S. Choi, H.D. Zhou, Physical Properties of Hastelloy(R) 
c # C-276 at cryogenic temperatures, J. Appl. Phys, 103, 064908, 2008
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   cInconel718       x    specific heat                     J/Kg K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   December 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     T0
      real     A1,A2,A3,A4,A5
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      real     Tmin,Tmax
      data     A1  / 0.41309481   / ,  A2  /-0.013004747 / ,
     &         A3  / 0.001506583  / ,  A4  /-0.000102024 / ,
     &         A5  / 3.53773E-06  /
      data     AA  / 33.25540448  / ,  BB  / 0.00033495   / ,
     &         CC  /-5.805231077  / ,  DD  / 53.53830618  / 
      data     a   / 52.14775361  / ,  b   /  4.561405177 / ,
     &         c   / 7.808266233  / ,  d   /  0.324667238 / 
      data     na  / 0.999063622  / ,  nb  /  1.99999986  / ,
     &         nc  /  2.54414531  / ,  nd  /  5.979402104 / 
      data     T0  / 22.14886733  /
      data     Tmin / 1.0/, Tmax / 300.0/
      save    
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      if(TT.le.T0) then

         cInconel718 = A1*T + A2*T**2 + A3*TT**3 + A4*TT**4 + A5*TT**5

      else
      
         cInconel718 = AA*TT**na/(1+TT/a)**na + BB*TT**nb/(1+TT/b)**nb + 
     &                 CC*TT**nc/(1+TT/c)**nc + DD*TT**nd/(1+TT/d)**nd       

      endif

c *
      return
      end
c ######################################################################
      real function kInconel718(T)
c ######################################################################
c #
c # Thermal conductivity of Inconel 718
c #
c # Range: 2 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # J.Lu, E.S. Choi, H.D. Zhou, Physical Properties of Hastelloy(R) 
c # C-276 at cryogenic temperatures, J. Appl. Phys, 103, 064908, 2008
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   kInconel718       x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   December 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      real     Tmin,Tmax
      data     AA  / 158.4804294  / ,  BB  /-462.2129276  / ,
     &         CC  /-0.320011253  / ,  DD  / 0.021326475  / 
      data     a   / 69.7108803   / ,  b   / 18.97513987  / ,
     &         c   / 0.135767286  / ,  d   / 1.797541177  / 
      data     na  / 1.44063238   / ,  nb  / 3.271282301  / ,
     &         nc  /  2.393231955 / ,  nd  / 2.887803913  / 
      data     Tmin / 1.0/, Tmax / 300.0/
      save    
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      kInconel718 = AA*TT   /(a+TT)**na + BB*TT**2/(b+TT)**nb + 
     &              CC*TT**3/(c+TT)**nc + DD*TT**4/(d+TT)**nd       

c *
      return
      end
c ######################################################################
      real function rInconel718(T)
c ######################################################################
c #
c # Electrical resistivity of Inconel 718
c #
c # Range: 0 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # Cryocomp v3.0
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   rInconel718       x    resistivity                       Ohm m
c #
c # Author : L.Bottura at CryoSoft
c # Version: 1.0   October 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     A,B,nb
      real     Tmin,Tmax
      data     A   /  11.8 / ,  B  / 0.00056648 / ,
     &         nb  / 1.189305878 /
      data     Tmin   / 0.0/, Tmax   / 300.0/
      save
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      rInconel718 = 1.0e-7 * (A + B*TT**nb)
	
c *
      return
      end