c ######################################################################
c #
c #                 POLYIMIDE PROPERTIES PACKAGE
c #                 ----------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of Polyimide (Kapton)
c #
c ######################################################################

c ######################################################################
      real function dPolyimide(T)
c ######################################################################
c #
c # Density of Polyimide (Kapton)
c #
c # Range: 0 <= T <= inf K
c #
c #                        References
c #                        ----------
c # http://en.wikipedia.org/wiki/Polyimide
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   dPolyimide        x    density                           Kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   October 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      

c * local variables

c *      
      dPolyimide = 1430.0
c *

      return
      end
c ######################################################################
      real function cPolyimide(T)
c ######################################################################
c #
c # Specific heat of Polyimide (Kapton)
c #
c # Range: 1 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # NIST Cryogenic Properites Database, at:
c # http://cryogenics.nist.gov/MPropsMAY/material%20properties.htm
c # referring to: Thermal Conductivity of a Polyimide Film Between 4.2 
c # and 300K,With and Without Alumina Particles as Filler, D.L. Rule, 
c # D.R. Smith, and L.L. Sparks, NISTIR 3948, August 1990.
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   cPolyimide        x    specific heat                     J/Kg K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 4.0   October 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      real     Tmin,Tmax
      data     AA  /   0.00156459 / ,  BB  /  6.56E-05    / ,
     &         CC  /  2.367381154 / ,  DD  / -6.030154373 / 
      data     a   / 78.29189203  / ,  b   /  6.231065699 / ,
     &         c   /  1.671794693 / ,  d   /  1.353253377 / 
      data     na  /  2.974620102 / ,  nb  /  8.63450373  / ,
     &         nc  /  6.702909446 / ,  nd  /  7.625169796 / 
      data     Tmin / 1.0/, Tmax / 300.0/
      save    
c * local variables
      real     TT
c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
      
      cPolyimide = AA*TT**na/(1+TT/a)**na + BB*TT**nb/(1+TT/b)**nb + 
     &             CC*TT**nc/(1+TT/c)**nc + DD*TT**nd/(1+TT/d)**nd       
c *
      return
      end
c ######################################################################
      real function kPolyimide(T)
c ######################################################################
c #
c # Thermal conductivity of Polyimide (Kapton)
c #
c # Range: 4 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # NIST Cryogenic Properites Database, at:
c # http://cryogenics.nist.gov/MPropsMAY/material%20properties.htm
c # referring to: (1) Thermal Conductivity of a Polyimide Film Between 
c # 4.2 and 300K,With and Without Alumina Particles as Filler, 
c # D.L. Rule, D.R. Smith, and L.L. Sparks, NISTIR 3948, August 1990.
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   kPolyimide        x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 4.0   October 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      real     Tmin,Tmax
      data     AA  /   2958.15305 / ,  BB  /   -4391.32924 / ,
     &         CC  /   -718.14120 / ,  DD  /    0.11661277 / 
      data     a   /  27.93383622 / ,  b   /   20.46539107 / ,
     &         c   /  27.70728517 / ,  d   /   5.736704051 / 
      data     na  /   4.04396724 / ,  nb  /   5.200018451 / ,
     &         nc  /   5.14441119 / ,  nd  /   3.897138904 / 
      data     Tmin / 4.0/, Tmax / 300.0/
      save    
c * local variables
      real     TT
c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)
      
      kPolyimide = AA*TT   /(a+TT)**na + BB*TT**2/(b+TT)**nb + 
     &             CC*TT**3/(c+TT)**nc + DD*TT**4/(d+TT)**nd        
c *

      return
      end