c ######################################################################
c #
c #                  Sn-40Pb PROPERTIES PACKAGE
c #                  ------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of Sn-40Pb
c #
c ######################################################################

c ######################################################################
      real function dSn40Pb(T)
c ######################################################################
c #
c # Density of Sn-40Pb
c #
c # Range: 0 <= T <= inf K
c #
c #                        References
c #                        ----------
c # Cryocomp v3.0
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   dSn40Pb         x    density                           Kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   June 2015
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      

c * local variables

c *      
      dSn40Pb = 8400.0
c *

      return
      end
c ######################################################################
      real function cSn40Pb(T)
c ######################################################################
c #
c # Specific heat of Sn-40Pb
c #
c # Range: 1 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # MISSING
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   cSn40Pb         x    specific heat                     J/Kg K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   June 2015
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     Tmin,Tmax,T0,T1
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
c
      data     Tmin / 1.0 /, Tmax / 300.0/
      data     T0 / 3.96249314 /
c
      save    
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      if(TT.ge.1.and.TT.le.T0) then

      AA = -0.07848998
      BB = 0.2150118
      CC = -0.42863307
      DD = 0.06224209
      a = 1.89412709
      b = 556.143928
      c = 0.20145037
      d = 0.00086726
      na = -0.10237772
      nb = -0.06338306
      nc = 0.65668303
      nd = 0.31793398

      else

      AA = -0.0002679
      BB = -0.39223444
      CC = 1.11558347
      DD = -1.06506974
      a = 18.7914061
      b = 43.8271896
      c = 6.10665608
      d = 3.14878533
      na = 4.50255658
      nb = 1.22694566
      nc = 2.24090761
      nd = 3.38478332

      endif

         cSn40Pb = AA*TT**1/(1+TT/a)**na + BB*TT**2/(1+TT/b)**nb + 
     &             CC*TT**3/(1+TT/c)**nc + DD*TT**4/(1+TT/d)**nd       

      return
      end
c ######################################################################
      real function kSn40Pb(T)
c ######################################################################
c #
c # Thermal conductivity of Sn-40Pb
c #
c # Range: 2 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # MISSING
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   kSn40Pb          x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   June 2015
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     Tmin,Tmax,T0
      real     rho0,rho273,RRR
      real     alpha,alpha2,beta
      real     L0,K0
      real     m,n,arg1,arg2
      real     W0,Wi,Wi0
      real     l
c *
      data     Tmin / 2.0/, Tmax / 300.0/
      data     T0 / 22.702953 /
      data     rho273 / 1.50E-07 / , RRR / 26.4214669 /
      data     alpha2 / 2.1156885E-08 /
      data     L0 / 2.443E-08 / , K0 / 5.74E+01 /
      data     m / 3.092523 /, n / 3.0255307 /
      data     l / 0.20328615 /
      save    
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      rho0 = rho273/(RRR-1)
      beta = rho0/L0
      arg1 = (m-n)*(m+l)
      arg2 = (TT-T0)/T0
      alpha = alpha2*(beta/n/alpha2)**arg1
      W0 = beta/TT
      Wi = alpha*TT**n
      Wi0 = Wi+W0

      if(TT.le.T0) then

         kSn40Pb = 1/Wi0

      else

         kSn40Pb = 1/Wi0 + K0*(1-exp(-arg2))

      endif

c *
      return
      end
c ######################################################################
      real function rSn40Pb(T)
c ######################################################################
c #
c # Electrical resistivity of Sn-40Pb
c #
c # Range: 0 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # MISSING
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   rSn40Pb         x    resistivity                       Ohm m
c #
c # Author : L.Bottura at CryoSoft
c # Version: 1.0   June 2015
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     RRR,rho273,rho0,rhoi,rhoi0
      real     p1,p2,p3,p4,p5,p6,p7
      real     arg
      real     Tmin,Tmax
c
      data     RRR / 45 /, rho273 / 1.50E-07 /
      data     p1 / 3.98307546E-14 /, p2 / 3.47905728 /,
     &         p3 / 3.6576564E+9 /, p4 / -1.10 /,
     &         p5 / 0.0 /, p6 / 1.0 / ,
     &         p7 / 0.333 /
      data     Tmin   / 0.0/, Tmax   / 300.0/
      save
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      rho0 = rho273/(RRR-1)
      arg = (p5/TT)**p6
      rhoi = p1*TT**p2/(1.+p1*p3*TT**(p2+p4)*exp(-arg))
      rhoi0 = (p7*rhoi*rho0)/(rhoi+rho0)

      rSn40Pb = rho0+rhoi+rhoi0
	
c *
      return
      end