c ######################################################################
c #
c #                  Ti-6Al-4V PROPERTIES PACKAGE
c #                  ----------------------------
c # Contains functions for the calculation of the thermo-physical
c # properties of Ti alloy Ti-6Al-4V
c #
c ######################################################################

c ######################################################################
      real function dTi6Al4V(T)
c ######################################################################
c #
c # Density of Ti alloy Ti-6Al-4V
c #
c # Range: 0 <= T <= inf K
c #
c #                        References
c #                        ----------
c # http://en.wikipedia.org/wiki/Titanium_alloy
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   dTi6Al4V          x    density                           kg/m**3
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   March 2013
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables      

c * local variables

c *      
      dTi6Al4V = 4430.0
c *

      return
      end
c ######################################################################
      real function cTi6Al4V(T)
c ######################################################################
c #
c # Specific heat of Ti alloy Ti-6Al-4V
c #
c # Range: 1 <= T <= 1144 K
c #
c #                        References
c #                        ----------
c # E. W. Collings, Materials Properties Handbook: Titanium Alloys
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   cTi6Al4V          x    specific heat                     J/kg K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   March 2012
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     T0
      real     A1,A2,A3
      real     AA,BB,CC,DD,a,b,c,d,na,nb,nc,nd
      real     Tmin,Tmax
      data     A1  / 0.051260473  / ,  A2  / 0.0         / ,
     &         A3  / 9.1378765e-4 /
      data     AA  /-4.4786194e-1 / ,  BB  / 7.3037135e-2 / ,
     &         CC  /-3.2281487e-3 / ,  DD  / 1.14178e-9   / 
      data     a   / 22.55888946  / ,  b   / 70.661558    / ,
     &         c   / 166.3477529  / ,  d   / 2000.0       / 
      data     na  / 2.000162161  / ,  nb  / 2.411017148  / ,
     &         nc  / 2.565595763  / ,  nd  / 4.058120738  / 
      data     T0  / 30.19268093  /
      data     Tmin / 1.0/, Tmax / 1144.0/
      save    
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      if(TT.le.T0) then

         cTi6Al4V = A1*TT + A2*TT**2 + A3*TT**3

      else
      
         cTi6Al4V = AA*TT**na/(1+TT/a)**na + BB*TT**nb/(1+TT/b)**nb + 
     &              CC*TT**nc/(1+TT/c)**nc + DD*TT**nd/(1+TT/d)**nd       

      endif

c *
      return
      end
c ######################################################################
      real function kTi6Al4V(T)
c ######################################################################
c #
c # Thermal conductivity of Ti alloy Ti-6Al-4V
c #
c # Range: 0.2 <= T <= 300 K
c #
c #                        References
c #                        ----------
c # A low temperature thermal conductivity database,Adam L. Woodcraft
c # and Adam Gray, CP1185, Low Temperature Detectors LTD 13, Proceedings
c # of the 13th International Workshop edited by B. Cabrera, A. Miller, 
c # and B. Young, 2009 American Institute of Physics
c # W. Ziegler, J. Mullins, and S. Hwa, Advances in Cryogenic 
c # Engineering 8, 268 (1963)
c # O. Umezawa, and K. Ishikawa, Cryogenics 32, 873–80 (1992).
c # M. Barucci, L. Lolli, L. Risegari, and G. Ventura, Cryogenics 48, 
c # 166–168 (2008).
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   kTi6Al4V          x    thermal conductivity              W/m K
c #
c #
c # Author : L.Bottura at Cryosoft
c # Version: 1.0   March 2013
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     A,B,C,D
      real     Tmin,Tmax
      data     A  / -1.495793436 / ,  B  / 1.984098724 / ,
     &         C  / -0.693703203 / ,  D  / 0.111921925 / 
      data     Tmin / 0.2/, Tmax / 300.0/
      save    
c * local variables
      real     TT,arg,logT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

c *
      logT = log10(TT)
      arg = A + B*logT + C*logT**2 + D*logT**3

c *
      kTi6Al4V = 10.0**arg

c *
      return
      end
c ######################################################################
      real function rTi6Al4V(T)
c ######################################################################
c #
c # Electrical resistivity of Ti alloy Ti-6Al-4V
c #
c # Range: 1 <= T <= 1100 K
c #
c #                        References
c #                        ----------
c # W. Lepkowski and J. Holladay, "Report on the Physical Properties of 
c # Titanium and Titanium Alloys, TML 73, Battelle Memorial Institute, 
c # Columbus, 1957
c # H. Deem et al., Trans. Metal Soc, AJME, 212, 520, 1958
c #
c # variable          I/O    meaning                           units
c # --------------------------------------------------------------------
c #   T               x      absolute temperature              K
c #   rTi6Al4V          x    resistivity                       Ohm m
c #
c # Author : L.Bottura at CryoSoft
c # Version: 1.0   March 2013
c #
c ######################################################################
      implicit none
c * external variables
      real     T
c * fit variables
      real     A,B,C
      real     Tmin,Tmax
      data     A   / 14.83301068 / ,  B  / 9.394832465 / ,
     &         C  /-5.640352091 /
      data     Tmin   / 1.0/, Tmax   / 1100.0/
      save
c * local variables
      real     TT

c *
      TT=T
      TT=min(TT,Tmax)
      TT=max(TT,Tmin)

      rTi6Al4V = 1.0e-7 * (A + B*(TT/1e3) + C*(TT/1e3)**2)
	
c *
      return
      end